Home
DevOps
SAP tables

SAP tables: categories, key tables and internal tables

How SAP describes and stores its data in the ABAP Dictionary, what each table category means, what changed in SAP S/4HANA, the tables you reach for every week, and how internal tables work in ABAP.

SE11
ABAP Dictionary
SAP S/4HANA
ABAP internal tables

By Luiz C. Mariani · Updated 30 October 2026

Dictionary: Display TableSE11

Transparent TableCSKS

StatusActive

Short Description · Cost Center Master Data

FieldKeyData elementTypeLength

MANDTMANDTCLNT3

KOKRSKOKRSCHAR4

KOSTLKOSTLCHAR10

DATBIDATBIDATS8

DATABDATABDATS8

BUKRSBUKRSCHAR4

PRCTRPRCTRCHAR10

Delivery class A · Text table CSKTContents

What is an SAP table?

Every SAP table is defined once, in the ABAP Dictionary (transaction SE11). For a transparent table, the dictionary definition and the table on the database share the same name and the same fields, so the dictionary is also the map of the database.

Every table has a primary key. In client-dependent tables the first key field is the client (MANDT, or RCLNT in the Universal Journal), which keeps each client's data apart in one database.

A field has no type of its own: it points to a data element (meaning, labels, F1 help), which points to a domain (type, length, allowed values). That chain is why the same company code field looks and behaves the same on every screen.

Business data falls into three groups: master data (cost centers, materials, business partners), transaction data (documents and their line items) and customizing (company codes, document types). Knowing the group tells you where to look and who maintains it.

From domain to table

Four dictionary objects stand behind every column you see in SE16N. The company code is the classic example.

1 · DomainBUKRSTechnical type CHAR 4, with table T001 as its value table.
2 · Data elementBUKRSThe meaning: labels "Company Code", F1 documentation, and the domain it uses.
3 · FieldBKPF-BUKRSA column of a table. ACDOCA-RBUKRS uses the same data element under another name.
4 · TableBKPFKey MANDT, BUKRS, BELNR, GJAHR, plus technical settings and a delivery class.

Other dictionary objects you will meet

Structure
Fields with no data on the database. Used for interfaces and screens, and included in tables, like ACDOC_SI_00 inside ACDOCA.
Table type
The global definition of an internal table: row type, table category and key, reusable in any program.
Check table and foreign key
A field's allowed values come from another table's key: BUKRS is checked against T001. This is how SAP models relationships.
Text table
Language-dependent texts kept apart, with SPRAS in the key: SKAT for SKA1, CSKT for CSKS, MAKT for MARA.
Views
Database, projection, maintenance and help views, defined in SE11. Maintenance views let SM30 edit related customizing tables together.
CDS view entity
Views written in ABAP Core Data Services, in ABAP Development Tools. The data model behind Fiori apps and ABAP Cloud, such as I_JournalEntryItem.
Search help
The F4 list of values for a field, with its own selection fields and result list.
Lock object
Logical locks (enqueue) so two users cannot change the same record at the same time.

Table categories

The table category says whether a physical table exists for a dictionary definition, and how it is stored on the database. You see it in SE11 next to the table name, and in field TABCLASS of table DD02L.

Transparent table
TRANSP
Own table on the database
One database table per dictionary table, with the same name and fields. All business data and most customizing live here, and any SQL tool can read it.
Examples: BKPF, CSKS, ACDOCA, MATDOC
Structure
INTTAB
No data on the database
Defines the interface between programs, or between screens and programs. It can be included in tables and other structures.
Examples: BAPIRET2, ACDOC_SI_00
Append structure
APPEND
Adds fields to a table
Fields that belong to another table or structure but are a separate object in correction management, so you can add customer fields (ZZ or YY) without a modification.
Example: an append on MARA with ZZ fields
Pooled table
POOL
Shared table pool · converted in S/4HANA
Many small tables stored in one table pool: the pool's key is the table name plus the record key, and the other fields are compressed in one column. Used for control data such as screen sequences and program parameters.
Readable only through the SAP kernel, with no joins
Cluster table
CLUSTER
Shared table cluster · converted in S/4HANA
Several tables that share part of their key stored in one table cluster, with the rows of one object packed into one physical record. Fast to read a whole document, impossible to aggregate in the database.
Examples in SAP ECC: BSEG in cluster RFBLG, KONV in KOCLU
Generated view structure
VIEW
No data on the database
A structure the system generates for a view when it is activated, used as the interface to the runtime environment. You do not usually see it in the dictionary.
Created and changed by the system only

Pooled and cluster tables in SAP S/4HANA

Pool and cluster data is compressed by the SAP kernel in its own format, so the database cannot compute on it. On the way to SAP HANA these tables are converted to transparent tables (declustering and depooling, SAP Note 1892354). BSEG is a transparent table in SAP S/4HANA; KONV gave way to the new pricing table PRCD_ELEMENTS.

Before a migration

List the remaining pool and cluster tables from DD02L (TABCLASS = POOL or CLUSTER) and DD06L. SAP KBA 2634739 has the steps.

Delivery class and technical settings

Two attributes decide how a table behaves in client copies, transports and upgrades, and how the database stores and buffers it.

Delivery class (SE11 › Delivery and Maintenance)
Class	What the table holds	Example
`A`	Application data: master and transaction data	BKPF, CSKS
`C`	Customizing, maintained only by the customer	T001
`L`	Temporary data, delivered empty	—
`G`	Customizing protected against SAP updates: SAP can only insert new entries	—
`E`	Control table: SAP and the customer each have their own key range	—
`S`	System table maintained only by SAP; a change is a modification	—
`W`	System table whose contents travel with their own transport objects	—

Data class
APPL0 master data, APPL1 transaction data, APPL2 organization and customizing. It decides the storage area on databases that use one.
Buffering
Single records, a generic area or the full table kept in the application server's memory. Right for small customizing read all day, like T001; wrong for transaction data.
Log data changes
With the flag on and profile parameter rec/client set, changes are logged and can be read in SCU3. Common for audit-relevant customizing.

What changed in SAP S/4HANA

SAP HANA adds up line items fast enough that most totals and index tables are no longer needed. Many old tables live on as views, so reports still run, but where the data really sits has moved.

Finance
One Universal Journal
ACDOCA holds FI, CO, asset accounting, material ledger and margin analysis actuals. GLT0, FAGLFLEXT, BSIS, BSID, BSIK and their peers became compatibility views.
ACDOCA, ACDOCP and ACDOCU
Inventory
MATDOC
One material document table replaces MKPF and MSEG. Stock quantities in MARD, MCHB and their peers are calculated from it; the old names remain as compatibility views.
Sales
Leaner SD tables
VBUK and VBUP are gone: status fields sit in VBAK, VBAP, LIKP, LIPS and VBRK. Pricing results moved from KONV to PRCD_ELEMENTS.
Master data
Business partner first
Customers and suppliers are created as business partners (BUT000). KNA1 and LFA1 stay, linked through CVI_CUST_LINK and CVI_VEND_LINK.
Field lengths
Longer keys
The material number can have up to 40 characters. Interfaces and custom code that assume 18 need a look.
Development
Views over tables
Code built for ABAP Cloud reads released CDS views, such as I_JournalEntryItem, instead of tables. Classic ABAP can still read tables directly.

Compatibility views: a SELECT on BSIS, COEP or MSEG still works, but writing to them does not. The data from before the conversion stays readable through the V_<table>_ORI views, for example V_COEP_ORI (SAP Note 1976487).

Key SAP tables by area

The tables you will reach for most, with their primary key and a transaction that shows the data. Pick an area. For how they join, see SAP table relationships.

General ledger, documents and payments. In SAP S/4HANA the line items of every ledger are in ACDOCA; BKPF and BSEG still carry the FI document.

Table	Description	Type	Key fields	Transaction	Note
`T001`	Company codes	Customizing	BUKRS	OX02
`SKA1`	G/L account master (chart of accounts)	Master data	KTOPL, SAKNR	FS00
`SKAT`	G/L account texts	Text table	SPRAS, KTOPL, SAKNR	FS00
`SKB1`	G/L account master (company code)	Master data	BUKRS, SAKNR	FS00
`BKPF`	Accounting document header	Transaction data	BUKRS, BELNR, GJAHR	FB03
`BSEG`	Accounting document segment (entry view)	Transaction data	BUKRS, BELNR, GJAHR, BUZEI	FB03	Cluster table in SAP ECC, transparent in SAP S/4HANA
`BSET`	Tax data document segment	Transaction data	BUKRS, BELNR, GJAHR, BUZEI	FB03
`ACDOCA`	Universal Journal entry line items	Transaction data	RLDNR, RBUKRS, GJAHR, BELNR, DOCLN	FB03, FAGLL03H	One line per ledger
`ACDOCP`	Plan data line items	Transaction data	REQTSN, DATAPAKID, RECORD	Import Financial Plan Data app	Technical key: always filter on the plan category
`BSIS, BSID, BSIK`	Open item indexes: G/L, customers, suppliers	View in S/4HANA	—	FBL3N, FBL5N, FBL1N	Tables in SAP ECC
`REGUS`	Accounts blocked by payment proposal	Transaction data	KOART, BUKRS, KONKO	F110	LAUFD and LAUFI name the payment run that holds the block

Cost and profit center master data and CO documents. CO actuals are in ACDOCA in SAP S/4HANA; the old CO tables answer through views.

Table	Description	Type	Key fields	Transaction	Note
`TKA01`	Controlling areas	Customizing	KOKRS	OKKP
`CSKS`	Cost center master data	Master data	KOKRS, KOSTL, DATBI	KS03	Time-dependent: take the line valid on your date
`CSKT`	Cost center texts	Text table	SPRAS, KOKRS, KOSTL, DATBI	KS03
`CEPC`	Profit center master data	Master data	PRCTR, DATBI, KOKRS	KE53
`CEPCT`	Profit center texts	Text table	SPRAS, PRCTR, DATBI, KOKRS	KE53
`AUFK`	Order master data	Master data	AUFNR	KO03	Internal, production, maintenance and other orders
`COBK`	CO object: document header	Transaction data	KOKRS, BELNR	KSB5
`COEP`	CO object: line items (by period)	Transaction data	KOKRS, BELNR, BUZEI	KSB5	S/4HANA: value types 04 and 11 come from ACDOCA through view V_COEP
`COSP, COSS`	CO totals: external and internal postings	View in S/4HANA	LEDNR, OBJNR, GJAHR, WRTTP, VERSN, KSTAR, …	—	Actual totals are calculated from ACDOCA

Asset master data stays in the ANL* tables. Asset values and line items moved to ACDOCA with new Asset Accounting.

Table	Description	Type	Key fields	Transaction	Note
`ANLA`	Asset master record segment	Master data	BUKRS, ANLN1, ANLN2	AS03
`ANLZ`	Time-dependent asset allocations	Master data	BUKRS, ANLN1, ANLN2, BDATU	AS03	Cost center, plant and location over time
`ANLB`	Depreciation terms	Master data	BUKRS, ANLN1, ANLN2, AFABE, BDATU	AS03
`ANEP, ANEA, ANLP, ANLC`	Asset line items and value totals	View in S/4HANA	—	AW01N	Values are in ACDOCA in SAP S/4HANA

Material master by organizational level, and material documents. Stock quantities and values are calculated from MATDOC and ACDOCA in SAP S/4HANA.

Table	Description	Type	Key fields	Transaction	Note
`MARA`	General material data	Master data	MATNR	MM03	MATNR up to 40 characters in SAP S/4HANA
`MAKT`	Material descriptions	Text table	MATNR, SPRAS	MM03
`MARC`	Plant data for material	Master data	MATNR, WERKS	MM03
`MARD`	Storage location data for material	Master data	MATNR, WERKS, LGORT	MMBE	S/4HANA: stock quantities calculated from MATDOC
`MBEW`	Material valuation	Master data	MATNR, BWKEY, BWTAR	MM03	S/4HANA: values from ACDOCA and the material ledger
`MCHA`	Batches (plant level)	Master data	MATNR, WERKS, CHARG	MSC3N
`MATDOC`	Material documents	Transaction data	Technical key; use MBLNR, MJAHR, ZEILE	MIGO, MB51	Replaces MKPF and MSEG
`MKPF, MSEG`	Material document header and items	View in S/4HANA	MBLNR, MJAHR (+ ZEILE)	MB03	Tables in SAP ECC
`T001W`	Plants	Customizing	WERKS	OX10
`T001L`	Storage locations	Customizing	WERKS, LGORT	OX09
`T001K`	Valuation areas	Customizing	BWKEY	—	Links the valuation area to its company code

From purchase requisition to supplier invoice. EKBE is the history that ties a PO item to its goods receipts and invoices.

Table	Description	Type	Key fields	Transaction	Note
`EBAN`	Purchase requisition	Transaction data	BANFN, BNFPO	ME53N
`EKKO`	Purchasing document header	Transaction data	EBELN	ME23N
`EKPO`	Purchasing document item	Transaction data	EBELN, EBELP	ME23N
`EKET`	Schedule lines	Transaction data	EBELN, EBELP, ETENR	ME23N
`EKKN`	Account assignment in purchasing document	Transaction data	EBELN, EBELP, ZEKKN	ME23N
`EKBE`	History per purchasing document	Transaction data	EBELN, EBELP, ZEKKN, VGABE, GJAHR, BELNR, BUZEI	ME23N	VGABE 1 = goods receipt, 2 = invoice receipt
`RBKP`	Supplier invoice header	Transaction data	BELNR, GJAHR	MIR4
`RSEG`	Supplier invoice item (PO-related)	Transaction data	BELNR, GJAHR, BUZEI	MIR4
`EINA, EINE`	Purchasing info record: general and organizational data	Master data	INFNR; INFNR, EKORG, ESOKZ, WERKS	ME13

Order, delivery and billing, each with a header and an item table. VBFA records the document flow between them.

Table	Description	Type	Key fields	Transaction	Note
`VBAK`	Sales document header	Transaction data	VBELN	VA03
`VBAP`	Sales document item	Transaction data	VBELN, POSNR	VA03
`VBEP`	Schedule lines	Transaction data	VBELN, POSNR, ETENR	VA03
`VBPA`	Sales document partners	Transaction data	VBELN, POSNR, PARVW	VA03	POSNR 000000 = header partner
`LIKP`	Delivery header	Transaction data	VBELN	VL03N
`LIPS`	Delivery item	Transaction data	VBELN, POSNR	VL03N
`VBRK`	Billing document header	Transaction data	VBELN	VF03
`VBRP`	Billing document item	Transaction data	VBELN, POSNR	VF03
`VBFA`	Sales document flow	Transaction data	Preceding VBELV, POSNV → subsequent VBELN, POSNN	VA03	Read in either direction
`PRCD_ELEMENTS`	Pricing elements	Transaction data	KNUMV, KPOSN, STUNR, ZAEHK	VA03	Replaces KONV in SAP S/4HANA
`VBUK, VBUP`	Header and item status	Removed in S/4HANA	—	—	Status fields now in VBAK, VBAP, LIKP, LIPS, VBRK

Bills of material, routings, orders and projects. Objects with a status carry an object number (OBJNR) that leads to JEST.

Table	Description	Type	Key fields	Transaction	Note
`MAST`	Material to BOM link	Master data	MATNR, WERKS, STLAN, STLNR, STLAL	CS03
`STKO`	BOM header	Master data	STLTY, STLNR, STLAL, STKOZ	CS03
`STPO`	BOM item	Master data	STLTY, STLNR, STLKN, STPOZ	CS03
`PLKO`	Task list header (routing)	Master data	PLNTY, PLNNR, PLNAL, ZAEHL	CA03
`AFKO`	Order header data (PP orders)	Transaction data	AUFNR	CO03
`AFPO`	Order item	Transaction data	AUFNR, POSNR	CO03
`RESB`	Reservations and dependent requirements	Transaction data	RSNUM, RSPOS, RSART	CO03
`AFRU`	Order confirmations	Transaction data	RUECK, RMZHL	CO14
`PROJ`	Project definition	Master data	PSPNR	CJ20N
`PRPS`	WBS element master data	Master data	PSPNR	CJ20N	PSPHI points to the project in PROJ
`JEST`	Object status	Transaction data	OBJNR, STAT	—	Texts in TJ02T (system) and TJ30T (user status)

In SAP S/4HANA the business partner is the entry point. Customer and supplier tables stay, linked by the CVI tables.

Table	Description	Type	Key fields	Transaction	Note
`BUT000`	Business partner: general data	Master data	PARTNER	BP
`BUT100`	Business partner roles	Master data	PARTNER, RLTYP, DFVAL	BP
`CVI_CUST_LINK`	Business partner to customer link	Master data	PARTNER_GUID	BP	CUSTOMER = KNA1-KUNNR
`CVI_VEND_LINK`	Business partner to supplier link	Master data	PARTNER_GUID	BP	VENDOR = LFA1-LIFNR
`KNA1`	Customer master: general data	Master data	KUNNR	BP
`KNB1`	Customer master: company code	Master data	KUNNR, BUKRS	BP
`KNVV`	Customer master: sales data	Master data	KUNNR, VKORG, VTWEG, SPART	BP
`LFA1`	Supplier master: general data	Master data	LIFNR	BP
`LFB1`	Supplier master: company code	Master data	LIFNR, BUKRS	BP
`LFM1`	Supplier master: purchasing organization	Master data	LIFNR, EKORG	BP
`ADRC`	Addresses (central address management)	Master data	ADDRNUMBER, DATE_FROM, NATION	BP

The nota fiscal tables of the Brazilian localization. J_1BNFLIN points back to the billing document, invoice or material document that created the nota fiscal.

Table	Description	Type	Key fields	Transaction	Note
`J_1BNFDOC`	Nota fiscal header	Transaction data	DOCNUM	J1B3N
`J_1BNFLIN`	Nota fiscal line items	Transaction data	DOCNUM, ITMNUM	J1B3N	REFTYP and REFKEY point to the source document
`J_1BNFSTX`	Nota fiscal taxes per item	Transaction data	DOCNUM, ITMNUM, TAXTYP	J1B3N
`J_1BNFNAD`	Nota fiscal partners	Transaction data	DOCNUM, PARVW	J1B3N
`J_1BNFE_ACTIVE`	Electronic nota fiscal: current status	Transaction data	DOCNUM	J1BNFE	Access key and authorization status
`J_1BBRANCH`	Business places (branches)	Customizing	BUKRS, BRANCH	—

Key fields are shown without the client (MANDT or RCLNT). Check them in SE11 for your release.

How to find the table behind a field

Screens often show structures, not tables. Work through these steps until you land on the table that really stores the value.

F1, then Technical Information. It shows the table or structure and the field name behind the screen field.
If it is a structure, open the data element in SE11 and run the where-used list for tables.
Search DD03L in SE16N by FIELDNAME or ROLLNAME (the data element) to list every table that has the field.
Trace with ST05. Switch on the SQL trace, run the transaction and read which tables it selects from.
Search a value with SE16S across many tables, when you know a value but not where it lives.
For Fiori apps, find the CDS view the app reads and follow its data sources down to the tables in ABAP Development Tools.

Display and maintain table data
Transaction	What it does
`SE16SE16N`	Display table contents with selections, layouts and text tables
`SE16H`	Display with grouping, totals and joins. See the SE16H guide.
`SM30`	Maintain customizing tables and views that have a maintenance dialog
`SE54`	Generate the maintenance dialog (also from SE11 › Utilities › Table Maintenance Generator)
`SCU3`	Evaluate table change logs

Table access is controlled by authorization objects S_TABU_DIS (by authorization group, assigned in table TDDAT) and S_TABU_NAM (by table name).

Internal tables in ABAP

An internal table is a dynamic data object in program memory: any number of rows with one common row type. It is ABAP's tool for mass data, from a list read with one SELECT to a lookup table inside a loop.

Three things define it: the row type, the table category and the table key. The row type can be any non-generic type: elementary, a structure, a table type or a reference, from the dictionary, a class or interface, or the program itself.

	Database table	Internal table
Lives in	The database	Program memory
Lifetime	Permanent	While the program runs
Defined in	SE11 or a CDS table entity	The program, or a dictionary table type
Read with	ABAP SQL	READ, LOOP, table expressions

Table categories of internal tables
Category	Managed by	Primary key	Access	Use it for
Standard	Row index	Always non-unique, can be empty	Index or key; a key read is a linear search	Filling, appending and looping over everything
Sorted	Row index, kept in key order	UNIQUE or NON-UNIQUE	Index or key; binary search on the key	Reads and loops on a leading part of the key
Hashed	Hash function	Always unique	Key only, same time at any size; no index	Large lookups by the full key

Generic categories
For typing parameters and field symbols: ANY TABLE accepts every category, INDEX TABLE only standard and sorted tables.
Table keys
One primary key, plus optional named secondary keys (sorted or hashed) used with USING KEY. table_line makes the whole row the key.
Avoid DEFAULT KEY
The standard key takes every character-like and byte-like component, which is rarely what you mean. Name the key fields, or write WITH EMPTY KEY.

Statements and expressions

Classic statements

READ TABLE
LOOP AT
INSERT … INTO TABLE
APPEND
MODIFY
DELETE
SORT
COLLECT

Modern ABAP (7.40 and later)

itab[ … ]
line_exists( )
lines( )
VALUE #( )
FOR
REDUCE
FILTER
CORRESPONDING
LOOP AT … GROUP BY

Examples

Classic ABAPModern ABAPFast lookups

Classic statements

TYPES: BEGIN OF ty_line,
         col1 TYPE i,
         col2 TYPE i,
       END OF ty_line.

DATA: line TYPE ty_line,
      itab TYPE STANDARD TABLE OF ty_line WITH EMPTY KEY.

" 1. Fill the table: INSERT appends to a standard table
DO 10 TIMES.
  line-col1 = sy-index.
  line-col2 = sy-index ** 2.
  INSERT line INTO TABLE itab.
ENDDO.

" 2. Read all rows in a loop
LOOP AT itab INTO line.
  WRITE: / line-col1, line-col2.
ENDLOOP.

" 3. Assign the fifth row to an inline field symbol
READ TABLE itab INDEX 5 ASSIGNING FIELD-SYMBOL(<line>).
IF sy-subrc = 0.
  WRITE: / <line>-col1, <line>-col2.
ENDIF.

What it shows

A structured row type, a standard table filled row by row, a loop over all rows and an index read of the fifth row.

Tip

Always check sy-subrc after READ TABLE: if the row does not exist, the field symbol stays unassigned and using it dumps.

The same job with expressions (ABAP 7.40 and later)

TYPES: BEGIN OF ty_line,
         col1 TYPE i,
         col2 TYPE i,
       END OF ty_line,
       tt_lines TYPE STANDARD TABLE OF ty_line WITH EMPTY KEY.

" 1. Build the table in one expression
DATA(itab) = VALUE tt_lines( FOR i = 1 UNTIL i > 10
                             ( col1 = i  col2 = i * i ) ).

" 2. Loop with an inline field symbol
LOOP AT itab ASSIGNING FIELD-SYMBOL(<line>).
  cl_demo_output=>write( |{ <line>-col1 } { <line>-col2 }| ).
ENDLOOP.

" 3. Table expression instead of READ TABLE
IF lines( itab ) >= 5.
  DATA(fifth) = itab[ 5 ].
  cl_demo_output=>write( fifth ).
ENDIF.

cl_demo_output=>display( ).

What it shows

VALUE with FOR builds the table, ASSIGNING avoids copying rows, and itab[ 5 ] reads a row without READ TABLE.

Tip

A table expression raises CX_SY_ITAB_LINE_NOT_FOUND when the row is missing. Guard it with lines( ) or line_exists( ), or add OPTIONAL inside VALUE #( ).

Read once, look up many times with a hashed table

TYPES: BEGIN OF ty_cc,
         kokrs TYPE kokrs,
         kostl TYPE kostl,
         prctr TYPE prctr,
       END OF ty_cc.

" One line per cost center: unique key
DATA cost_centers TYPE HASHED TABLE OF ty_cc
                  WITH UNIQUE KEY kokrs kostl.

" Only the record valid today, so the key stays unique
SELECT kokrs, kostl, prctr
  FROM csks
  WHERE kokrs = @lv_kokrs
    AND datab <= @sy-datum
    AND datbi >= @sy-datum
  INTO TABLE @cost_centers.

" Constant-time lookups inside the loop
LOOP AT postings ASSIGNING FIELD-SYMBOL(<p>).
  <p>-prctr = VALUE #( cost_centers[ kokrs = <p>-kokrs
                                    kostl = <p>-kostl ]-prctr OPTIONAL ).
ENDLOOP.

What it shows

One SELECT fills a hashed table keyed by controlling area and cost center; the loop then finds each profit center without another database call.

Tip

CSKS is time-dependent. Without the date filter, a cost center with two validity periods gives two rows with the same key, and the SELECT into a unique hashed table dumps.

Performance rules that pay off

Never read a large standard table by key inside a loop over another large table: use a sorted or hashed table, or a secondary key.
Read the database once into a hashed table instead of a SELECT inside a LOOP.
With FOR ALL ENTRIES, check the driver table is not empty first: an empty one selects every row.
Use ASSIGNING or REFERENCE INTO for wide rows, so rows are not copied.

Frequently asked questions

What is a transparent table in SAP?

A table defined in the ABAP Dictionary that has exactly one table on the database, with the same name and fields. Almost all business data in SAP S/4HANA is stored in transparent tables.

What is the difference between a table and a structure?

Both are lists of fields defined in SE11. A table stores rows on the database; a structure stores nothing and only describes data passed between programs and screens, or included in a table.

Do pool and cluster tables still exist in SAP S/4HANA?

Not for application data. They are converted to transparent tables when the system moves to SAP HANA, so tables such as BSEG can be read and aggregated with plain SQL.

Which table stores the G/L line items in SAP S/4HANA?

ACDOCA, the Universal Journal, with one line per ledger. BKPF still holds the document header and BSEG the entry view of FI documents.

How do I find which table a field is stored in?

Press F1 on the field and open Technical Information. If it shows a structure, use the where-used list of the data element in SE11, search table DD03L, or trace the transaction with ST05.

What is the difference between standard, sorted and hashed internal tables?

Standard tables are accessed by index and searched row by row; sorted tables keep their key order and use a binary search; hashed tables find a row by its unique key in the same time at any size, but have no index.

What is MANDT in SAP tables?

The client. It is the first key field of client-dependent tables and keeps the data of each client apart. ABAP SQL fills it automatically, so you never select it yourself.

What is an SAP table?

From domain to table

Other dictionary objects you will meet

Structure

Table type

Check table and foreign key

Text table

Views

CDS view entity

Search help

Lock object

Table categories

Transparent table

Structure

Append structure

Pooled table

Cluster table

Generated view structure

Pooled and cluster tables in SAP S/4HANA

Delivery class and technical settings

Data class

Buffering

Log data changes

What changed in SAP S/4HANA

One Universal Journal

MATDOC

Leaner SD tables

Business partner first

Longer keys

Views over tables

Key SAP tables by area

Finance

Controlling

Assets

Materials

Purchasing

Sales

Production & projects

Business partner

Brazil NF

How to find the table behind a field

Internal tables in ABAP

Generic categories

Table keys

Avoid DEFAULT KEY

Statements and expressions

Examples

What it shows

Tip

What it shows

Tip

What it shows

Tip

Performance rules that pay off

Frequently asked questions

Related pages

References